如何在代码中注册OCX控件

[susu8988]

在ＤＥＬＰＨＩ程序中注册ＯＬＥ／ＣＯＭ控件
　　在用ＤＥＬＰＨＩ编写程序时，充分利用他人的成果无疑是一条捷径。我们用的控件有的是带源码
的ＰＡＳ文件，有的是ＤＣＵ／ＯＢＪ文件；而ＯＬＥ／ＣＯＭ控件也是不可缺少的，由于ＯＬＥ／ＣＯＭ
控件不仅可以由ＤＥＬＰＨＩ开发，还可由ＶＢ、ＶＣ、ＰＢ等其它编程语言开发，因而它可以使我们的
ＤＥＬＰＨＩ应用程序功能更为强大，例如用一个ＭＰ３播放控件我们就可以编写自己的ＭＰ３播放程序，
用ＡＤＯ对象我们的数据库程序就可能不再依赖ＢＤＥ。
　　不过ＯＬＥ／ＣＯＭ控件是需要首先注册才能使用的。通常使用ＯＬＥ／ＣＯＭ控件，首先需要用
ＷＩＮＤＯＷＳ自己提供的注册程序RegSvr32.EXE来注册或卸载，如“RegSvr32.EXE Mp3Play.OCX”或
“RegSvr32.EXE Mp3Play.OCX /u”。不过如果要求我们的软件用户自己来注册ＯＬＥ／ＣＯＭ控件，那
可不是一个好主意，因为我们完全可以自己在程序中注册ＯＬＥ／ＣＯＭ控件的。下面将讨论如何在
ＤＥＬＰＨＩ程序中注册最为常见的ＤＬＬ／ＯＣＸ类型的ＯＬＥ／ＣＯＭ控件。

一、注册ＯＬＥ／ＣＯＭ控件的原理
　　在标准ＯＬＥ／ＣＯＭ控件中，有两个函数DllRegisterServer、DllUnregisterServer可调用，其中
DllRegisterServer函数用于注册ＯＬＥ／ＣＯＭ控件，DllUnregisterServer用于卸载ＯＬＥ／ＣＯＭ
控件，两个函数的原型均为：function : HResult。我们可用LoadLibrary装载ＤＬＬ／ＯＣＸ文件，
用GetProcAddress获取DllRegisterServer和DllUnregisterServer两个函数的指针，然后再直接运行这
两个函数即可实现注册和卸载ＯＬＥ／ＣＯＭ控件的操作，从而代替ＷＩＮＤＯＷＳ系统的RegSvr32.exe
实现ＯＬＥ／ＣＯＭ控件的注册和卸载。

二、实现过程
　　上面的原理很简单，实现起来也就不难了，前提是必须熟悉动态加载ＤＬＬ函数的过程。具体的实现
过程我们可以通过下面的程序代码及注释来理解。
{ 注册一个DLL形式或OCX形式的OLE/COM控件
参数strOleFileName为一个DLL或OCX文件名，
参数OleAction表示注册操作类型，1表示注册，0表示卸载
返回值True表示操作执行成功，False表示操作执行失败
}
function RegisterOleFile (strOleFileName : STRING; OleAction : Byte ) : BOOLEAN;
const
RegisterOle = 1;//注册
UnRegisterOle = 0;//卸载
type
TOleRegisterFunction = function : HResult;//注册或卸载函数的原型
var
hLibraryHandle : THandle;//由LoadLibrary返回的DLL或OCX句柄
hFunctionAddress: TFarProc;//DLL或OCX中的函数句柄，由GetProcAddress返回
RegFunction : TOleRegisterFunction;//注册或卸载函数指针
begin
Result := FALSE;
//打开OLE/DCOM文件，返回的DLL或OCX句柄
hLibraryHandle := LoadLibrary(PCHAR(strOleFileName));
if (hLibraryHandle > 0) then//DLL或OCX句柄正确
try
//返回注册或卸载函数的指针
if (OleAction = RegisterOle) then//返回注册函数的指针
hFunctionAddress := GetProcAddress(hLibraryHandle, pchar('DllRegisterServer'))
else//返回卸载函数的指针
hFunctionAddress := GetProcAddress(hLibraryHandle, pchar('DllUnregisterServer'));
if (hFunctionAddress <> NIL) then//注册或卸载函数存在
begin
RegFunction := TOleRegisterFunction(hFunctionAddress);//获取操作函数的指针
if RegFunction >= 0 then //执行注册或卸载操作，返回值>=0表示执行成功
result := true;
end;
finally
FreeLibrary(hLibraryHandle);//关闭已打开的OLE/DCOM文件
end;
end;

三、应用举例
　　在我们的应用例子中，OpenDialog1（TOpenDialog）用于选择一个DLL/COM文件，editOleFileName
（TEdit）用于保存DLL/COM文件名称，radiogroupOleAction（TRadioGroup）用于选择操作类型（０－卸载、
１－注册），memo1（TMemo）用来显示操作成功或失败的信息。具体的例子还是看程序源码吧。

//选择一个DLL/COM文件
procedure TForm1.Button2Click(Sender: TObject);
begin
if OpenDialog1.execute then //指定一个DLL/COM文件
editOleFileName.text := OpenDialog1.FileName ;
end;

//注册一个DLL形式或OCX形式的OLE/COM控件
procedure TForm1.Button1Click(Sender: TObject);
begin
if editOleFileName.text = '' then exit;//没有指定文件名则不予处理
if RegisterOleFile( editOleFileName.text, radiogroupOleAction.ItemIndex )
then//操作成功
memo1.lines.add( DatetimeToStr( now ) + '----'+ editOleFileName.text
+ radiogroupOleAction.Items[ radiogroupOleAction.ItemIndex ] + '成功！' )
else//操作失败
memo1.lines.add( DatetimeToStr( now ) + '----'+ editOleFileName.text
+ radiogroupOleAction.Items[ radiogroupOleAction.ItemIndex ] + '失败！' );
end;

　　把注册ＯＬＥ／ＣＯＭ控件功能作成一个ＯＬＥ／ＣＯＭ或一般的ＤＬＬ供其它程序调用，可
以使其它应用程序也具有注册ＯＬＥ／ＣＯＭ控件的功能。
　　以上程序在PWIN98+DELPHI3.0下调试通过